Современные автомобили включают в себя несколько десятков разнообразных датчиков. И все эти датчики регулярно обмениваются информацией с другими датчиками/устройствами автомобиля. Причем автомобили с каждым годом становятся все "умнее" и поэтому количество датчиков в них все больше увеличивается. В автомобилях сегодняшнего дня находят широкое применение системы автономного вождения, системы безопасности с автоматически срабатывающими подушками безопасности, системы контроля давления в шинах, круиз-контроль и т.д. В большинстве случаев информация, поступающая от этих датчиков, является критически важной. Например, если сработает датчик столкновения, которому срочно нужно передать сигнал на раскрытие подушек безопасности, а ему это помешают сделать какие-либо сигналы/процессы в электронной системе автомобиля. В этом случае жизнь людей в автомобиле может оказаться под угрозой. Поэтому в автомобилях не используют такие широко распространенные в обычной электронике протоколы передачи данных как UART, SPI или I2C. Вместо них конструкторы автомобилей отдают предпочтение значительно более надежным протоколам передачи данных, таким как LIN, CAN, FlexRay и т.д.
Наибольшее распространение среди этих "надежных" протоколов получил стандарт (протокол) CAN. Этот стандарт широко применяется не только в электронных системах современных автомобилей, но и во многих других промышленных устройства, в которых критически важна надежная передача данных. Достаточно подробную информацию о стандарте CAN можно прочитать в соответствующей статье Википедии. Мы же в данной статье рассмотрим обмен данными между двумя платами Arduino с помощью протокола CAN.
Краткие сведения о протоколе CAN
CAN (Controller Area Network – сеть контролеров) представляет собой протокол (стандарт) последовательной связи, разработанный для промышленных и автомобильных приложений. Это ориентированный на обмен сообщениями протокол, используемый для связи между множеством (несколькими) устройств. Когда различные CAN устройства соединены между собой как показано на следующем рисунке, они формируют сеть, которая работает наподобие центральной нервной системы человека и позволяет любому устройству общаться с любым другим устройством в этой сети.
CAN-сеть состоит из двух проводников (CAN High и CAN Low) и обеспечивает двунаправленную передачу данных. На практике под CAN-сетью обычно подразумевается сеть топологии "шина" с физическим уровнем в виде дифференциальной пары. Передача ведется кадрами, которые могут принимать все узлы сети. Для доступа к такой шине выпускаются специализированные микросхемы (модули) – драйверы CAN-шины.
Обычно скорость передачи по CAN-шине варьируется от 50 Кбит/с до 1 Мбит/с, а дальность связи лежит в диапазоне от 40 метров (на скорости 1 Мбит/с) до 1000 метров (на скорости 50 Кбит/с).
Формат CAN сообщений
В CAN-сети данные передаются в виде сообщений определенного формата. Этот формат состоит из большого числа сегментов, но двумя основными сегментами является идентификатор (identifier) и данные (data), которые и позволяют передавать и принимать сообщения по CAN-шине.
Идентификатор (Identifier) – также известен под именами CAN ID и PGN (Parameter Group Number). Он используется для идентификации CAN устройств в CAN-сети. Длина идентификатора составляет 11 или 29 бит в зависимости от того какой тип протокола CAN используется:
- Standard (стандартный) CAN: 0-2047 (11-bit);
- Extended (расширенный) CAN: 0-229-1 (29-bit).
Data – это данные, которые необходимо передать от одного устройства другому. Длина данных может составлять от 0 до 8 байт.
Data Length Code (DLC) (длина поля данных): может принимать значения от 0 до 8 в зависимости от количества байт для передачи.
Проводники, используемые в CAN
CAN протокол работает по двум проводникам, именуемыми CAN_H и CAN_L, для передачи и приема информации. Оба проводника работают как дифференциальная линия, что означает что CAN сигнал (0 или 1) представляет собой разность потенциалов между CAN_L и CAN_H. Если эта разность положительна и больше определенного минимального уровня напряжения, то это 1, а если эта разность отрицательна – то это 0.
Обычно в протоколе CAN используется кабель с витыми жилами. Как показано на выше приведенном рисунке, на обоих концах CAN-сети включается 120-омный резистор для обеспечения баланса в линии.
Сравнение CAN с SPI и I2C
На нашем сайте мы ранее уже рассматривали использование в платах Arduino протоколов SPI и I2C, поэтому давайте сравним данные протоколы с протоколом CAN.
| Параметр | SPI | I2C | CAN |
| Скорость | 3-10 Мбит/с | стандарт: 100 Кбит/с;
быстрый: 400 Кбит/с; быстрый: 3,4 Мбит/с; |
10 Кбит/с - 1 Мбит/с (зависит от длины используемых проводов) |
| Тип | синхронный | синхронный | асинхронный |
| Число проводов | 3+ (MISO, MOSI, SCK, SS1, SS2…SS(n)) | ||
| Дуплекс | полный дуплекс | полудуплекс | полудуплекс |
По скорости стандарт CAN не в лидерах, но его главным "козырем" является высокая надежность связи.
Применения CAN протокола
- В связи с чрезвычайно высокой надежностью и устойчивостью CAN протокола он широко применяется в автомобилях, промышленных механизмах, сельском хозяйстве, медицинском оборудовании и т.д.
- В связи с небольшим количеством используемых проводников CAN протокол исключительно удобен для применения в автомобилях.
- Устройства на основе CAN протокола отличаются низкой стоимостью.
- В CAN-сеть (шину) легко добавлять и удалять новые устройства.
Использование протокола CAN в Arduino
Поскольку платы Arduino не имеют в своем составе встроенного CAN порта, то для реализации связи между ними по данному протоколу мы будем использовать внешние CAN модули MCP2515. Эти модули подключаются к плате Arduino по интерфейсу SPI.
CAN модуль (контроллер шины CAN) MCP2515
Модуль MCP2515 включает в себя CAN контроллер MCP2515, который представляет собой высокоскоростной CAN приемопередатчик. Соединение модуля MCP2515 с микроконтроллером осуществляется с помощью интерфейса SPI, поэтому его легко подключить ко всем микроконтроллерам с данным интерфейсом.
Начинающим изучение CAN-шины целесообразно начинать именно с этого модуля ввиду его простоты и легкости подключения к большинству современных микроконтроллеров.
Основные технические характеристики модуля MCP2515:
- включает в себя высокоскоростной CAN приемопередатчик TJA1050;
- размеры модуля: 40×28mm;
- управление по интерфейсу SPI с возможностью подключения к CAN-шине нескольких устройств;
- кварцевый генератор на 8 МГц;
- сопротивление на концах 120 Ом;
- включает независимый ключ, светодиодный индикатор, индикатор мощности;
- поддерживает скорости передачи данных до 1 Мбит/с;
- низкий потребляемый ток в режиме ожидания;
- возможность подключения до 112 устройств (узлов).
Назначение контактов (распиновка) CAN модуля MCP2515 представлено в следующей таблице.
| Наименование контакта | Назначение контакта |
| VCC | контакт питания 5 В |
| GND | общий провод (земля) |
| CS | SPI SLAVE select pin (Active low) (выбор ведомого) |
| SO | SPI master input slave output lead |
| SI | SPI master output slave input lead |
| SCLK | контакт синхронизации SPI |
| INT | контакт прерывания MCP2515 |
В данном проекте мы будем передавать данные, считываемые с датчика температуры и влажности DHT11 платой Arduino Nano, плате Arduino Uno с помощью CAN модуля MCP2515.
Необходимые компоненты
- Плата Arduino Uno (купить на AliExpress).
- Плата Arduino Nano (купить на AliExpress).
- Датчик температуры и влажности DHT11 (купить на AliExpress).
- ЖК дисплей 16х2 (купить на AliExpress).
- MCP2515 CAN Module (контроллер шины CAN MCP2515) – 2 шт. (купить на AliExpress).
- Потенциометр 10 кОм (купить на AliExpress).
- Макетная плата.
- Соединительные провода.
Схема проекта
Схема проекта для связи между двумя платами Arduino с помощью протокола CAN и модулей MCP2515 представлена на следующем рисунке.
Соединения на передающей стороне:
| Компонент - контакт | Arduino Nano |
| MPC2515 - VCC | +5V |
| MPC2515 - GND | GND |
| MPC2515 - CS | D10 (SPI_SS) |
| MPC2515 - SO | D12 (SPI_MISO) |
| MPC2515 - S I | D11 (SPI_MOSI) |
| MPC2515 - SCK | D13 (SPI_SCK) |
| MPC2515 - INT | D2 |
| DHT11 - VCC | +5V |
| DHT11 - GND | GND |
| DHT11 - OUT | A0 |
Соединения на приемной стороне:
| Компонент - контакт | Arduino Uno |
| MPC2515 - VCC | +5V |
| MPC2515 - GND | GND |
| MPC2515 - CS | 10 (SPI_SS) |
| MPC2515 - SO | 12 (SPI_MISO) |
| MPC2515 - SI | 11 (SPI_MOSI) |
| MPC2515 - SCK | 13 (SPI_SCK) |
| MPC2515 - INT | 2 |
| LCD (ЖК дисплей) - VSS | GND |
| LCD - VDD | +5V |
| LCD - V0 | к среднему контакту потенциометра 10 кОм |
| LCD - RS | 3 |
| LCD - RW | GND |
| LCD - E | 4 |
| LCD - D4 | 5 |
| LCD - D5 | 6 |
| LCD - D6 | 7 |
| LCD - D7 | 8 |
| LCD - A | +5V |
| LCD - K | GND |
Соединения между двумя CAN модулями MCP2515:
H – CAN High
L – CAN Low
| MCP2515 (Arduino Nano) | MCP2515 (Arduino UNO) |
| H | H |
| L | L |
После сборки всей схемы на макетных платах у нас получилась следующая конструкция.
Объяснение программы для Arduino
Первым делом нам необходимо установить библиотеку для работы с протоколом CAN в Arduino IDE. Сначала скачайте ZIP файл библиотеки по следующей ссылке - Arduino CAN MCP2515 Library. Затем установите ее в Arduino IDE с помощью пункта меню Sketch -> Include Library -> Add .ZIP Library.
В нашем проекте мы код программы разделим на две части: для передающей части и для приемной части. Полные коды программ приведены к конце статьи, здесь же мы кратко рассмотрим их основные фрагменты.
Инициализация CAN модуля MCP2515
Для установления соединения платы Arduino с модулем MCP2515 выполните следующую последовательность шагов. Но перед этим убедитесь в том, что указанная выше библиотека CAN MCP2515 установлена в вашу Arduino IDE.
Шаг 1. Установите номер контакта, к которому подключена линия CS интерфейса SPI (10 по умолчанию).
|
1 |
MCP2515 mcp2515(10); |
Шаг 2. Установите скорость передачи и частоту кварцевого генератора.
|
1 |
mcp2515.setBitrate(CAN_125KBPS, MCP_8MHZ); |
Доступные скорости передачи:
CAN_5KBPS, CAN_10KBPS, CAN_20KBPS, CAN_31K25BPS, CAN_33KBPS, CAN_40KBPS, CAN_50KBPS, CAN_80KBPS, CAN_83K3BPS, CAN_95KBPS, CAN_100KBPS, CAN_125KBPS, CAN_200KBPS, CAN_250KBPS, CAN_500KBPS, CAN_1000KBPS.
Доступные частоты кварцевого генератора:
MCP_20MHZ, MCP_16MHZ, MCP_8MHZ
Шаг 3. Установите режимы.
|
1 2 3 |
mcp2515.setNormalMode(); mcp2515.setLoopbackMode(); mcp2515.setListenOnlyMode(); |
Объяснение программы для передающей части (Arduino Nano)
В передающей части к плате Arduino Nano подключен CAN модуль MCP2515 по интерфейсу SPI, а данные температуры и влажности, считываемые с датчика DHT11, передаются далее по CAN-шине.
Первым делом в программе подключим необходимые библиотеки: библиотеку SPI для использования интерфейса SPI, библиотеку MCP2515 для использования связи с помощью протокола CAN и библиотеку DHT для работы с датчиком DHT11. Ранее на нашем сайте мы уже рассматривали подключение датчика DHT11 к плате Arduino.
|
1 2 3 |
#include <SPI.h> #include <mcp2515.h> #include <DHT.h> |
Дадим название контакту, к которому подключен датчик DHT11 – это контакт A0 платы Arduino Nano.
|
1 |
#define DHTPIN A0 |
Также определим DHTTYPE как DHT11.
|
1 |
#define DHTTYPE DHT11 |
Определим переменную canMsg типа данных структура для хранения сообщений CAN формата.
|
1 |
struct can_frame canMsg; |
Установим номер контакта, к которому подключена линия CS интерфейса SPI (10 по умолчанию).
|
1 |
MCP2515 mcp2515(10); |
Также создадим объект dht класса DHT с параметрами DHT pin и DHTTYPE.
|
1 |
DHT dht(DHTPIN, DHTTYPE); |
В функции void setup():
Инициализируем связь по протоколу SPI.
|
1 |
SPI.begin(); |
Начнем считывание данных температуры и влажности с датчика DHT11.
|
1 |
dht.begin(); |
Сбросим в исходное состояние (RESET) модуль MCP2515 с помощью следующей команды:
|
1 |
mcp2515.reset(); |
Установим для модуля MCP2515 скорость передачи 500 кбит/с и частоту кварцевого генератора 8 МГц.
|
1 |
mcp2515.setBitrate(CAN_500KBPS,MCP_8MHZ); |
Установим модуль MCP2525 в обычный режим (normal mode).
|
1 |
mcp2515.setNormalMode(); |
В функции void loop():
Считаем значения температуры и влажности с датчика DHT11 и сохраним их в переменных целого типа h и t.
|
1 2 |
int h = dht.readHumidity(); int t = dht.readTemperature(); |
Далее установим идентификатору (CAN ID) значение 0x036 (на ваш выбор), DLC (длина поля данных) присвоим значение 8 (8 байт), запишем значения температуры и влажности в поля данных data[0] и data[1], в остальные поля данных запишем значения 0.
|
1 2 3 4 5 6 7 8 9 10 |
canMsg.can_id = 0x036; canMsg.can_dlc = 8; canMsg.data[0] = h; //Update humidity value in [0] canMsg.data[1] = t; //Update temperature value in [1] canMsg.data[2] = 0x00; //Rest all with 0 canMsg.data[3] = 0x00; canMsg.data[4] = 0x00; canMsg.data[5] = 0x00; canMsg.data[6] = 0x00; canMsg.data[7] = 0x00; |
После всего этого передадим сообщение по CAN-шине с помощью команды:
|
1 |
mcp2515.sendMessage(&canMsg); |
После выполнения этой команды значения температуры и влажности передадутся в виде сообщения по CAN-шине.
Объяснение программы для приемной части (Arduino Uno)
В приемной части нашего проекта к плате Arduino Uno подключены модуль MCP2515 и ЖК дисплей 16х2. Здесь плата Arduino Uno принимает значения температуры и влажности по CAN шине и отображает их на экране ЖК дисплея 16х2.
Первым делом в программе подключим используемые библиотеки: библиотеку SPI для использования интерфейса SPI, библиотеку MCP2515 для использования связи с помощью протокола CAN и библиотеку LiquidCrsytal для работы с ЖК дисплеем 16х2.
|
1 2 3 |
#include <SPI.h #include <mcp2515.h> #include <LiquidCrystal.h> |
Далее сообщим плате Arduino, к каким ее контактам подключен ЖК дисплей 16х2.
|
1 2 |
const int rs = 3, en = 4, d4 = 5, d5 = 6, d6 = 7, d7 = 8; LiquidCrystal lcd(rs, en, d4, d5, d6, d7); |
Определим переменную canMsg типа данных структура для хранения сообщений CAN формата.
|
1 |
struct can_frame canMsg; |
Установим номер контакта, к которому подключена линия CS интерфейса SPI (10 по умолчанию).
|
1 |
MCP2515 mcp2515(10); |
В функции void setup ():
Установим ЖК дисплей в режим работы 16x2 и отобразим на его экране приветственное сообщение.
|
1 2 3 4 5 6 7 |
lcd.begin(16,2); lcd.setCursor(0,0); lcd.print("CIRCUIT DIGEST"); lcd.setCursor(0,1); lcd.print("CAN ARDUINO"); delay(3000); lcd.clear(); |
Инициализируем связь по протоколу SPI.
|
1 |
SPI.begin(); |
Сбросим в исходное состояние (RESET) модуль MCP2515 с помощью следующей команды:
|
1 |
mcp2515.reset(); |
Установим для модуля MCP2515 скорость передачи 500 кбит/с и частоту кварцевого генератора 8 МГц.
|
1 |
mcp2515.setBitrate(CAN_500KBPS,MCP_8MHZ); |
Установим модуль MCP2525 в обычный режим (normal mode).
|
1 |
mcp2515.setNormalMode(); |
В функции void loop():
Следующая команда (с использованием оператора условия If) используется для приема сообщения из CAN-шины.
|
1 |
if (mcp2515.readMessage(&canMsg) == MCP2515::ERROR_OK) |
Если записанное условие if выполняется, данные принимаются и сохраняются в переменной canMsg, поле data [0] этой переменной будет содержать значение влажности, а поле data [1] – значение температуры. Мы будем сохранять эти значения в переменных целого типа (integer) x и y.
|
1 2 |
int x = canMsg.data[0]; int y = canMsg.data[1]; |
После успешного приема значений температуры и влажности мы выводим их на экран ЖК дисплея.
|
1 2 3 4 5 6 7 8 |
lcd.setCursor(0,0); lcd.print("Humidity : "); lcd.print(x); lcd.setCursor(0,1); lcd.print("Temp : "); lcd.print(y); delay(1000); lcd.clear(); |
Тестирование работы проекта
После того, как аппаратная часть проекта будет готова, загрузите коды программы в платы Arduino в передающей и приемной частях проекта. После этого при подаче питания на схемы вы должны увидеть, как значения температуры и влажности, считанные одной платой Arduino с датчика DHT11, передаются по CAN-шине другой плате Arduino, которая выводит эти принятые значения на экран ЖК дисплея. Мы для проверки правильности значений температуры использовали пульт от кондиционера, с помощью которого устанавливали температуру в комнате.
Исходный код программы (скетча)
Код программы для передающей части (Arduino Nano)
|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 |
#include <SPI.h> //Library for using SPI Communication #include <mcp2515.h> //Library for using CAN Communication #include <DHT.h> //Library for using DHT sensor #define DHTPIN A0 #define DHTTYPE DHT11 struct can_frame canMsg; MCP2515 mcp2515(10); DHT dht(DHTPIN, DHTTYPE); //initilize object dht for class DHT with DHT pin with STM32 and DHT type as DHT11 void setup() { while (!Serial); Serial.begin(9600); SPI.begin(); //инициализация связи по протоколу SPI dht.begin(); //начинаем считывать температуру и влажность с датчика DHT11 mcp2515.reset(); mcp2515.setBitrate(CAN_500KBPS,MCP_8MHZ); //устанавливаем скорость шины CAN 500 кбит/с и частоту кварцевого генератора 8 МГц mcp2515.setNormalMode(); } void loop() { int h = dht.readHumidity(); //считываем значение влажности int t = dht.readTemperature(); // считываем значение температуры canMsg.can_id = 0x036; // устанавливаем CAN id в 0x036 canMsg.can_dlc = 8; // длина поля данных CAN = 8 canMsg.data[0] = h; //обновляем значение влажности в поле [0] canMsg.data[1] = t; // обновляем значение температуры в поле [1] canMsg.data[2] = 0x00; //все остальные поля устанавливаем в 0 canMsg.data[3] = 0x00; canMsg.data[4] = 0x00; canMsg.data[5] = 0x00; canMsg.data[6] = 0x00; canMsg.data[7] = 0x00; mcp2515.sendMessage(&canMsg); //передаем CAN сообщение delay(1000); } |
Код программы для приемной части (Arduino Uno)
|
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 |
#include <SPI.h> //Library for using SPI Communication #include <mcp2515.h> //Library for using CAN Communication #include <LiquidCrystal.h> //Library for using LCD display const int rs = 3, en = 4, d4 = 5, d5 = 6, d6 = 7, d7 = 8; LiquidCrystal lcd(rs, en, d4, d5, d6, d7); //Define LCD display pins RS,E,D4,D5,D6,D7 struct can_frame canMsg; MCP2515 mcp2515(10); // SPI CS Pin 10 void setup() { lcd.begin(16,2); //устанавливаем режим работы ЖК дисплея 16x2 lcd.setCursor(0,0); //показываем приветственное сообщение lcd.print("CIRCUIT DIGEST"); lcd.setCursor(0,1); lcd.print("CAN ARDUINO"); delay(3000); lcd.clear(); SPI.begin(); //инициализируем связь по протоколу SPI Serial.begin(9600); //инициализируем последовательную связь со скоростью 9600 бод mcp2515.reset(); mcp2515.setBitrate(CAN_500KBPS,MCP_8MHZ); //устанавливаем скорость шины CAN 500 кбит/с и частоту кварцевого генератора 8 МГц mcp2515.setNormalMode(); //устанавливаем CAN-шину в обычный режим } void loop() { if (mcp2515.readMessage(&canMsg) == MCP2515::ERROR_OK) // To receive data (Poll Read) { int x = canMsg.data[0]; int y = canMsg.data[1]; //показываем принятые значения температуры и влажности на ЖК дисплее 16x2 lcd.setCursor(0,0); lcd.print("Humidity : "); lcd.print(x); lcd.setCursor(0,1); lcd.print("Temp : "); lcd.print(y); delay(1000); lcd.clear(); } } |
Видео, демонстрирующее работу проекта
Похожие статьи
(Проголосуй первым!)
Загрузка...